График функции вида y = f (x)

Plot[Tan[x],{x,-2Pi,2Pi},PlotRange->{-4,4},Exclusions->{Cos[x]==0},AspectRatio->Automatic]

График функции вида f(x)+f(y)=a

ContourPlot[x^2+y^2==9,{x,-4,4},{y,-4,4}]

График параметрической функции

ParametricPlot[{Sin[t],Sin[2t]},{t,0,2Pi}]

График в полярной системе координат

PolarPlot[1+Cos[t],{t,0,2Pi}]

a=1;
Grid[
{{PolarPlot[2a(1+Cos[t]),{t,0,2Pi},PlotLabel->Text[r=2a(1+Cos[t])]],
PolarPlot[2a(1-Cos[t]),{t,0,2Pi},PlotLabel->Text[r=2a(1-Cos[t])]]},
{PolarPlot[2a(1+Sin[t]),{t,0,2Pi},PlotLabel->Text[r=2a(1+Sin[t])]],
PolarPlot[2a(1-Sin[t]),{t,0,2Pi},PlotLabel->Text[r=2a(1-Sin[t])]]}}]

Анимированная циклоида

Clear["Global`*"]
R=1;
Manipulate[
Show[
ParametricPlot[{R(t-Sin[t]),R(1-Cos[t])},{t,0,n},PlotRange->{{-1,16},{-1,3}},AspectRatio->Automatic,PlotStyle->{Thick,Black}],
Graphics[{
Lighter[Blue],Line[{
{n R,R},
{R(n-Sin[n]),R(1-Cos[n])}
}],
Circle[{n R,R},{R,R}],
PointSize[Medium],Point[{n R ,R}],
Red,Point[{R(n-Sin[n]),R(1-Cos[n])}]}]
],
{n,10^(-16),15,0.01}
]

Анимированная кардиоида

Clear["Global`*"]
R=1;
Manipulate[
Show[
PolarPlot[2R(1+Cos[t]),{t,0,n},PlotRange->{{-3,5},{-4,4}},AspectRatio->Automatic,PlotStyle->{Thick,Black}],
Graphics[{
Lighter[Blue],Line[{
{2R Cos[n]+R,2R Sin[n]},
{2R(1+Cos[n])Cos[n],2R(1+Cos[n])Sin[n]}
}],
Circle[{R,0},{R,R}],
Rotate[Circle[{3R,0},{R,R}],n,{R,0}],
PointSize[Medium],Point[{2R Cos[n]+R,2R Sin[n]}],
Red,Point[{2R(1+Cos[n])Cos[n],2R(1+Cos[n])Sin[n]}]}]
],
{n,10^(-16),2Pi,0.01}
]